#
# Plot the velocity & stuff during the trip from Earth to AC
#    
# set terminal x11 0
# set output

set parametric

set key left
set trange [0:11.32]
set xrange [0:7.04]
set yrange [*:*]
set grid

set title "From Earth to Alpha Centaurus and back, In the Traveler's MCRF"
set xlabel "Ship's Time"

# Earth time at turnover and arrival
tt = 2.83
tf = 5.66

# Ship time at turnover and arrival
taut = 1.76
tauf = 3.52

# Distance at turnover and arrival
xt = 2
xf = 4

# Complemented time, for convenience
tc(t) = tf - t

# Velocity before and after turnover, and combined
v0(t) = t/sqrt(1 + t**2)
v1(t) = tc(t)/sqrt(1 + tc(t)**2)
v(t) = (t < tt)	     ? v0(t)  : \
       (t < tf)	     ? v1(t)  : \
       (t < tf + tt) ? -v0(t - tf) : \
       -v1(t - tf)

# Ship time before and after turnover, and combined
tau0(t) = log(t + sqrt(t**2 + 1))
tau1(t) = tauf - tau0(tf - t)
tau(t) = (t <= tt) ? tau0(t) : \
	(t <= tf)  ? tau1(t) : \
	(t <= tf + tt) ? tauf + tau0(t-tf) : \
	tauf + tau1(t-tf)

# Gamma
Gamma0(t) = 1/sqrt(1 - v(t)**2)
Gamma(t) = (t <= tf) ? Gamma0(t) : Gamma0(t - tf)

# Ship location before and after turnover, and combined
dx0(t) = sqrt(t**2 + 1) - 1
dx1(t) = xf - dx0(tc(t))
distance(t) = (t <= tt) ? dx0(t) : \
	(t <= tf) 	? dx1(t) : \
	(t <= tt + tf) 	? xf - dx0(t - tf) : \
	xf - dx1(t - tf)

# Earth time, simultaneous with the ship's "now", in the MCRF
ts0(t) = t/Gamma(t)
ts1(t) = tf - tc(t) * (xf + 1)/Gamma(t)
ts2(t) = t - (distance(t)/Gamma(t)) * v(t) * Gamma(t)
t_simultaneous(t) = (t < tt) ? ts0(t) : (t <= tf) ? ts1(t) : ts2(t)

# Difference between Earth-simultaneous time and Earth-ship time
ts_diff(t) = t_simultaneous(t) - t

# Derivative of Earth time wrt Ship's time
dtdT0(t) = 1/(1 + t**2)
dtdT1(t) = 5/(1 + (tf - t)**2)
dtdT_pre_tf(t) = (t<tt) ? dtdT0(t) : dtdT1(t)
dt_dTau(t) = (t < tf) ? dtdT_pre_tf(t) : dtdT_pre_tf(tf - (t - tf))

set xtics 0.5
set ytics 1

plot \
tau(t), v(t), \
tau(t), Gamma(t), \
tau(t), t_simultaneous(t)   with lines linewidth 2, \
tau(t), ts_diff(t) with lines linewidth 2, \
tau(t), dt_dTau(t) with lines linewidth 2, \
tau(t), t